#MIN_CONFIG(3.0.0)

AM_INIT_AUTOMAKE(yammi, 1.2.2)
AC_C_BIGENDIAN
AC_CHECK_KDEMAXPATHLEN

dnl -------------------------------
dnl Configure switches.
dnl -------------------------------

AH_TEMPLATE( [ENABLE_XMMS], [Support xmms as media player] )
AH_TEMPLATE( [ENABLE_GSTREAMER], [Support gstreamer as media player] )

AC_ARG_ENABLE( [xmms],
               AC_HELP_STRING( [--disable-xmms],
                               [disable support for xmms (don't need xmmsctrl)] ),
               configure_enable_xmms=$enableval,
               configure_enable_xmms=yes )

AC_ARG_ENABLE( [gstreamer],
	       AC_HELP_STRING( [--disable-gstreamer],
			       [disable support for gstreamer] ),
	       configure_enable_gstreamer=$enableval,
	       configure_enable_gstreamer=yes )


AC_MSG_NOTICE( [
 Requested:
 XMMS support .........: $configure_enable_xmms
 gstreamer support ....: $configure_enable_gstreamer
] )


dnl -------------------------------
dnl Checks for libraries.
dnl -------------------------------

dnl standard C++ library
AC_CHECK_LIB( stdc++, main, , AC_MSG_ERROR( [*** stdc++ library is required ***] ), )


dnl taglib check
dnl ------------

TAGLIB_REQ_VERSION="1.3";
AC_DEFUN([VERSION_TO_NUMBER], [`$1 | awk 'BEGIN { FS = "."; } { printf "%d",  ([$]1* 1000 + [$]2) * 1000 + [$]3;}'`])

AC_PATH_PROG(TAGLIB_CONFIG, taglib-config, no)

if test "x$TAGLIB_CONFIG" = "xno" ; then
    AC_MSG_ERROR( [*** taglib not found! ***] )
else
    AC_DEFINE(HAVE_TAGLIB, 1, [have TagLib])
    taglib_includes=[`$TAGLIB_CONFIG --cflags`]
    taglib_libs=[`$TAGLIB_CONFIG --libs`]
    taglib_version=[`$TAGLIB_CONFIG --version`]

    if test VERSION_TO_NUMBER(echo $taglib_version) -lt VERSION_TO_NUMBER(echo $TAGLIB_REQ_VERSION); then
        AC_MSG_ERROR( [*** taglib too old! ***] )
    fi
fi

AC_SUBST(taglib_includes)
AC_SUBST(taglib_libs)
LIBS="$taglib_libs $LIBS"
CFLAGS="$taglib_includes $CFLAGS"



dnl XMMS support (new version)
dnl --------------------------
if test "x$configure_enable_xmms" = "xyes"; then
    AM_PATH_XMMS(1.2.6, ,AC_MSG_ERROR([*** XMMS >= 1.2.6 not found - please install it or run configure script with --disable-xmms ***] ))
    LIBS="$XMMS_LIBS $LIBS"
    CFLAGS="$XMMS_CFLAGS $CFLAGS"
    AC_DEFINE( [ENABLE_XMMS], [1] )
fi



dnl GStreamer support
dnl -----------------
if test "x$configure_enable_gstreamer" = "xyes"; then
   KDE_CHECK_HEADER(kde/gstplay/play.h,configure_enable_gstreamer=yes,configure_enable_gstreamer=no)

   if test "x$configure_enable_gstreamer" = "xyes"; then
      AC_DEFINE( [ENABLE_GSTREAMER], [] )
      LIBS="$LIBS -lkdegst -lkdegstplay"
   fi 
fi

dnl ---------------------
dnl end of library checks
dnl ---------------------


AC_MSG_NOTICE( [
Configuration for $PACKAGE $VERSION :
--------------------------------
 ##############################################
 Source code location .: $srcdir
 Host System Type .....: $host
 Preprocessor .........: $CC $CPPFLAGS
 Compiler .............: $CC $CFLAGS $LIBFLAC_CFLAGS
 Linker ...............: $CC $LDFLAGS $LIBS $LIBFLAC_LIBS
 XMMS support .........: $configure_enable_xmms
 gstreamer support ....: $configure_enable_gstreamer
 Install path .........: $prefix
   If this path does not exist or is not the desired install path,
   you should re-run configure, giving a suitable path with the --prefix option
   For example ./configure --prefix=/opt/kde3

 Look for any WARNINGs output by the configure script (run ./configure --help to see all options).
 If you're satisfied, type 'make' to build $PACKAGE $VERSION,
 and then 'make install' for installation.
] )