ax_boost_iostreams

Test for IOStreams library from the Boost C++ libraries. The macro requires a preceding call to AX_BOOST_BASE. Further documentation is available at <http://randspringer.de/boost/index.html>.

This macro calls:

  AC_SUBST(BOOST_IOSTREAMS_LIB)

And sets:

  HAVE_BOOST_IOSTREAMS

AC_DEFUN([AX_BOOST_IOSTREAMS],
[
        AC_ARG_WITH([boost-iostreams],
        AS_HELP_STRING([--with-boost-iostreams@<:@=special-lib@:>@],
                   [use the IOStreams library from boost - it is possible to specify a certain library for the linker
                        e.g. --with-boost-iostreams=boost_iostreams-gcc-mt-d-1_33_1 ]),
        [
        if test "$withval" = "no"; then
                        want_boost="no"
        elif test "$withval" = "yes"; then
            want_boost="yes"
            ax_boost_user_iostreams_lib=""
        else
                    want_boost="yes"
                ax_boost_user_iostreams_lib="$withval"
                fi
        ],
        [want_boost="yes"]
        )

        if test "x$want_boost" = "xyes"; then
        AC_REQUIRE([AC_PROG_CC])
                CPPFLAGS_SAVED="$CPPFLAGS"
                CPPFLAGS="$CPPFLAGS $BOOST_CPPFLAGS"
                export CPPFLAGS

                LDFLAGS_SAVED="$LDFLAGS"
                LDFLAGS="$LDFLAGS $BOOST_LDFLAGS"
                export LDFLAGS

        AC_CACHE_CHECK(whether the Boost::IOStreams library is available,
                                           ax_cv_boost_iostreams,
        [AC_LANG_PUSH([C++])
                 AC_COMPILE_IFELSE(AC_LANG_PROGRAM([[@%:@include <boost/iostreams/filtering_stream.hpp>
                                                                                         @%:@include <boost/range/iterator_range.hpp>
                                                                                        ]],
                                  [[std::string  input = "Hello World!";
                                                                 namespace io = boost::iostreams;
                                                                         io::filtering_istream  in(boost::make_iterator_range(input));
                                                                         return 0;
                                   ]]),
                             ax_cv_boost_iostreams=yes, ax_cv_boost_iostreams=no)
         AC_LANG_POP([C++])
                ])
                if test "x$ax_cv_boost_iostreams" = "xyes"; then
                        AC_DEFINE(HAVE_BOOST_IOSTREAMS,,[define if the Boost::IOStreams library is available])
                BN_BOOST_IOSTREAMS_LIB=boost_iostreams
            BOOSTLIBDIR=`echo $BOOST_LDFLAGS | sed -e 's/@<:@^\/@:>@*//'`
            if test "x$ax_boost_user_iostreams_lib" = "x"; then
                for libextension in `ls $BOOSTLIBDIR/libboost_iostreams*.{so,a}* | sed 's,.*/,,' | sed -e 's;^libboost_iostreams\(.*\)\.so.*$;\1;' -e 's;^libboost_iostreams\(.*\)\.a*$;\1;'` ; do
                     ax_lib=${BN_BOOST_IOSTREAMS_LIB}${libextension}
                                    AC_CHECK_LIB($ax_lib, exit,
                                 [BOOST_IOSTREAMS_LIB="-l$ax_lib"; AC_SUBST(BOOST_IOSTREAMS_LIB) link_iostreams="yes"; break],
                                 [link_iostreams="no"])
                                done

            else
               for ax_lib in $ax_boost_user_iostreams_lib $BN_BOOST_IOSTREAMS_LIB-$ax_boost_user_iostreams_lib; do
                                      AC_CHECK_LIB($ax_lib, main,
                                   [BOOST_IOSTREAMS_LIB="-l$ax_lib"; AC_SUBST(BOOST_IOSTREAMS_LIB) link_iostreams="yes"; break],
                                   [link_iostreams="no"])
                  done

            fi
                        if test "x$link_iostreams" = "xno"; then
                                AC_MSG_ERROR(Could not link against $ax_lib !)
                        fi
                fi

                CPPFLAGS="$CPPFLAGS_SAVED"
        LDFLAGS="$LDFLAGS_SAVED"
        fi
])

Copyright © 2007 Thomas Porschberg <thomas@randspringer.de>

Copying and distribution of this file, with or without modification, are permitted in any medium without royalty provided the copyright notice and this notice are preserved.