#
# $Id: cmnlint.awk,v 1.6 2003/09/23 15:42:20 jmmv Exp $
# Verify correctness of generic files.
#
# Copyright (c) 2003 Julio M. Merino Vidal.
#
# Redistribution and use in source and binary forms, with or without
# modification, are permitted provided that the following conditions
# are met:
# 1. Redistributions of source code must retain the above copyright
#    notice, this list of conditions and the following disclaimer.
# 2. Redistributions in binary form must reproduce the above copyright
#    notice, this list of conditions and the following disclaimer in
#    the documentation and/or other materials provided with the
#    distribution.
# 3. Neither the name of the author nor the names of contributors may
#    be used to endorse or promote products derived from this software
#    without specific prior written permission.
#
# THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS''
# AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
# TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
# PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR
# CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
# SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
# LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF
# USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND
# ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
# OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
# OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
# SUCH DAMAGE.
#

function warn(msg) {
    print FILENAME "[" FNR "]: " msg > "/dev/stderr"
    error = 1
}

BEGIN {
    skip = 0
    error = 0
}

/NOLINT_BEGIN/ {
    skip = 1
    next
}

/NOLINT_END/ {
    skip = 0
    next
}

/NOLINT/ {
    next
}

{
    if (skip)
        next

    if (length > 79)
        warn("Line too long to fit on screen")
}

/^ *\t+/ {
    if (! match(FILENAME, "Makefile"))
        warn("Tab character used for indentation");
}

/[ \t]+$/ {
    warn("Trailing spaces or tabs");
}

/[\$]Id:.*$/ {
    if (match($0, "[0-9][0-9][0-9][0-9]/[0-9][0-9]/[0-9][0-9]"))
        year = substr($0, RSTART, 4);
}

/Copyright \(c\)[ \t]+20/ {
    if (! match($0, year))
        warn("Copyright sentence does not include " year);
}

END {
    if (skip)
        warn("Missing NOLINT_END");
    if (error)
        exit 1
}