dnl Configure.in script for CvsGraph
dnl Most of the stuff is gathered from other
dnl scripts that seem to do a pretty good job.

AC_INIT(cvsgraph.c)
AC_CONFIG_HEADER(config.h)

AC_PROG_CC
AC_PROG_LEX
AC_PROG_YACC

LEXFLAGS="-8"
LEXSPEED="-Cf"
INCL=""

dnl Extra libraries 'with'-options
AC_ARG_WITH(gd-inc,[  --with-gd-inc=DIR       location of the gd includes],
		[INCL="${INCL} -I${withval}"
		])

AC_ARG_WITH(gd-lib,[  --with-gd-lib=DIR       location of the gd library],
		[LIBS="${LIBS} -L${withval}"
		])

LIBS="$LIBS -lgd"
LIBPATH=""

AC_ARG_WITH(freetype-lib,[  --with-freetype-lib=DIR    location of freetype library],
		[LIBS="${LIBS} -L${withval}"
		])

AC_ARG_WITH(freetype2-lib,[  --with-freetype2-lib=DIR    location of freetype2 library],
		[LIBS="${LIBS} -L${withval}"
		])

AC_ARG_WITH(png-inc,[  --with-png-inc=DIR      location of png includes],
		[INCL="${INCL} -I${withval}"
		])

AC_ARG_WITH(png-lib,[  --with-png-lib=DIR      location of png library],
		[LIBS="${LIBS} -L${withval}"
		])

AC_ARG_WITH(jpeg-inc,[  --with-jpeg-inc=DIR    location of jpeg includes],
		[INCL="${INCL} -I${withval}"
		])

AC_ARG_WITH(jpeg-lib,[  --with-jpeg-lib=DIR    location of jpeg library],
		[LIBS="${LIBS} -L${withval}"
		])

AC_ARG_WITH(z-inc,[  --with-z-inc=DIR        location of zlib includes],
		[INCL="${INCL} -I${withval}"
		])

AC_ARG_WITH(z-lib,[  --with-z-lib=DIR        location of zlib library],
		[LIBS="${LIBS} -L${withval}"
		])

AC_ARG_ENABLE(speed,[  --disable-speed         Turn off lex table optimization reducing speed and size of executable],
		[if test "$enableval" = "no"; then LEXSPEED=""; fi])

if test "x$LEXSPEED" != "x"
then
  LEXFLAGS="$LEXFLAGS $LEXSPEED"
fi

CPPFLAGS="$CPPFLAGS $INCL"
CFLAGS="$CFLAGS $INCL"

dnl Tests for gcc
if test "x${GCC}" = "xyes"
then
  CFLAGS="$CFLAGS -Wall"
  AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
                  AC_TRY_RUN([
int main(void) {
  static int Array[[3]];
  unsigned int B = 3;
  int i;
  for(i=0; i<B; i++) Array[[i]] = i - 3;
  exit( Array[[1]] != -2 );
}],
    ac_cv_c_gcc_strength_bug="no",
    ac_cv_c_gcc_strength_bug="yes",
    ac_cv_c_gcc_strength_bug="yes") )
  if test "$ac_cv_c_gcc_strength_bug" = "yes"
  then
    CFLAGS="$CFLAGS -fno-strength-reduce"
  fi
fi

AC_CACHE_CHECK( "sizes of int and void *", ac_cv_c_size_int_ptr,
	  AC_TRY_RUN([
int main(void) {
  return sizeof(int) == sizeof(void *);
}],
    ac_cv_c_size_int_ptr="no",
    ac_cv_c_size_int_ptr="yes",
    ac_cv_c_size_int_ptr="yes") )

AC_CACHE_CHECK( "sizes of long and void *", ac_cv_c_size_long_ptr,
	  AC_TRY_RUN([
int main(void) {
  return sizeof(long) == sizeof(void *);
}],
    ac_cv_c_size_long_ptr="no",
    ac_cv_c_size_long_ptr="yes",
    ac_cv_c_size_long_ptr="yes") )

AC_CACHE_CHECK( "sizes of long long and void *", ac_cv_c_size_longlong_ptr,
	  AC_TRY_RUN([
int main(void) {
  return sizeof(long long) == sizeof(void *);
}],
    ac_cv_c_size_longlong_ptr="no",
    ac_cv_c_size_longlong_ptr="yes",
    ac_cv_c_size_longlong_ptr="yes") )

if test "$ac_cv_c_size_int_ptr" = "no"
then
	if test "$ac_cv_c_size_long_ptr" = "no"
	then
		if test "$ac_cv_c_size_longlong_ptr" = "no"
		then
			echo "** The size of an integer is not equal to a pointer."
			echo "   There are currently assumtions in the app that"
			echo "   prevents it from running if these sizes are not"
			echo "   equal."
			echo "   Please configure with a compiler that uses the"
			echo "   same sizes for ints and pointers."
			exit 1
		else
			INTTYPE="long long"
		fi
	else
		INTTYPE="long"
	fi
else
	INTTYPE="int"
fi

dnl Check getopt.h because Solaris 8 doesn't have one
AC_CHECK_HEADER(getopt.h, [ AC_DEFINE(HAVE_GETOPT_H) ])

dnl Check sys/wait.h because Windows doesn't have one
AC_CHECK_HEADER(sys/wait.h, [ AC_DEFINE(HAVE_SYS_WAIT_H) ])

dnl Make sure the gd header is here
AC_CHECK_HEADER( gd.h,[ have_gd_h="yes" ],[ have_gd_h="no" ])

if test "$have_gd_h" != "yes"; then
echo
	echo "** The GD library is required for CvsGraph to function."
	echo "   Get it from http://www.boutell.com, compile it and"
	echo "   use either --with-gd-lib=DIR and --with-gd-inc=DIR to specify"
	echo "   its location. You might also have to use --with-z-inc, --with-z-lib"
	echo "   and --with-png-inc, --with-png-lib for gd versions 1.6 and higher."
	echo "   Check config.log for more information on the problem. If your system"
        echo "   has libgd installed, you probably mis the gd.h header file."
	exit 1
fi

dnl Checks for libraries.
AC_CHECK_LIB(m, sqrt, [
	AC_DEFINE(LIBM)
	MATHLIBS="-lm"
	])

AC_CHECK_LIB(z, compress, [
	ac_have_libz="yes"
	LIBZ="-lz"
	] , [
	ac_have_libz="no"
	] , ${LIBPATH} ${MATHLIBS} )

AC_CHECK_LIB(freetype, FT_Load_Glyph, [
	ac_have_libfreetype="yes"
	LIBFT="-lfreetype"
	] , [
	ac_have_libfreetype="no"
	] , ${LIBPATH} ${MATHLIBS} )

AC_CHECK_LIB(ttf, TT_Load_Glyph, [
	ac_have_libttf="yes"
	LIBTT="-lttf"
	] , [
	ac_have_libttf="no"
	] , ${LIBPATH} ${MATHLIBS} )

AC_CHECK_LIB(png, png_create_read_struct , [
	ac_have_libpng="yes"
	LIBPNG="-lpng"
	] , [
	ac_have_libpng="no"
	] , ${LIBPATH} ${LIBZ} ${MATHLIBS} )

AC_CHECK_LIB(jpeg, jpeg_CreateCompress, [
	ac_have_libjpeg="yes"
	LIBJPEG="-ljpeg"
	] , [
	ac_have_libjpeg="no"
	] , ${LIBPATH} ${MATHLIBS} )

dnl Check which libraries we need to add
OLIBS="${LIBS}"
LIBS="${LIBS} ${MATHLIB}"
AC_CACHE_CHECK( "whether libpng needs -lz", ac_cv_png_needs_z,
	  AC_TRY_LINK_FUNC( png_create_read_struct, [
	ac_cv_png_needs_z="no"
	] , [
	ac_cv_png_needs_z="yes"
	] ) )
LIBS="${OLIBS}"


OLIBS="${LIBS}"
LIBS="${LIBS} ${LIBFT} ${LIBTT} ${LIBJPEG} ${MATHLIB}"
AC_CACHE_CHECK( "whether libgd needs -lpng", ac_cv_gd_needs_png,
	  AC_TRY_LINK_FUNC( gdImagePng, [
	ac_cv_gd_needs_png="no"
	] , [
	ac_cv_gd_needs_png="yes"
	] ) )
LIBS="${OLIBS}"

OLIBS="${LIBS}"
LIBS="${LIBS} ${LIBFT} ${LIBTT} ${LIBPNG} ${LIBZ} ${MATHLIB}"
AC_CACHE_CHECK( "whether libgd needs -ljpeg", ac_cv_gd_needs_jpeg,
	  AC_TRY_LINK_FUNC( gdImageJpeg, [
	ac_cv_gd_needs_jpeg="no"
	] , [
	ac_cv_gd_needs_jpeg="yes"
	] ) )
LIBS="${OLIBS}"

OLIBS="${LIBS}"
LIBS="${LIBS} ${LIBFT} ${LIBJPEG} ${LIBPNG} ${LIBZ} ${MATHLIB}"
AC_CACHE_CHECK( "whether libgd needs -lttf", ac_cv_gd_needs_ttf,
	  AC_TRY_LINK_FUNC( gdImageStringTTF, [
	ac_cv_gd_needs_ttf="no"
	] , [
	ac_cv_gd_needs_ttf="yes"
	] ) )
LIBS="${OLIBS}"

OLIBS="${LIBS}"
LIBS="${LIBS} ${LIBTT} ${LIBJPEG} ${LIBPNG} ${LIBZ} ${MATHLIB}"
AC_CACHE_CHECK( "whether libgd needs -lfreetype", ac_cv_gd_needs_freetype,
	  AC_TRY_LINK_FUNC( gdImageStringFT, [
	ac_cv_gd_needs_freetype="no"
	] , [
	ac_cv_gd_needs_freetype="yes"
	] ) )
LIBS="${OLIBS}"

if test "$ac_cv_gd_needs_freetype" = "yes"
then
	if test "$ac_have_libfreetype" != "yes" -a "$ac_have_libttf" != "yes"
	then
		echo "** WARNING: Required library libfreetype not found"
	fi
	LIBS="${LIBS} ${LIBFT}"
fi

if test "$ac_cv_gd_needs_ttf" = "yes"
then
	if test "$ac_have_libttf" != "yes" -a "$ac_have_libfreetype" != "yes"
	then
		echo "** WARNING: Required library libttf not found"
	fi
	LIBS="${LIBS} ${LIBTT}"
fi

if test "$ac_cv_gd_needs_jpeg" = "yes"
then
	if test "$ac_have_libjpeg" != "yes"
	then
		echo "** WARNING: Required library libjpeg not found"
	fi
	LIBS="${LIBS} ${LIBJPEG}"
fi

if test "$ac_cv_gd_needs_png" = "yes"
then
	if test "$ac_have_libpng" != "yes"
	then
		echo "** WARNING: Required library libpng not found"
	fi
	LIBS="${LIBS} ${LIBPNG}"
	if test "$ac_cv_png_needs_z" = "yes"
	then
		if test "$ac_have_libz" != "yes"
		then
			echo "** WARNING: Required library libz not found"
		fi
		LIBS="${LIBS} ${LIBZ}"
	fi
fi

LIBS="${LIBS} ${MATHLIBS}"

dnl which version of gd do we have here?
AC_CHECK_LIB(gd, gdImageGif, [
	AC_DEFINE(HAVE_IMAGE_GIF)
	have_gifs="yes"
	] ,
	have_gifs="no"
	)

dnl The new versions of libgd include gifs again after the patent expired.
dnl So this check should not be required anymore.
dnl if test "${have_gifs}" = "yes"
dnl then
dnl	echo "** You have a very old GD library. Please consider"
dnl	echo "   upgrading to a more recent version (1.8.4 or newer)."
dnl	echo "   --Note that f.x. ViewCVS needs CvsGraph to generate PNG"
dnl	echo "     images and ancient GD libraries might contain many bugs."
dnl	echo "     However, if you need GIFs, then you must stick to this"
dnl	echo "     old version."
dnl fi

AC_CHECK_LIB(gd, gdImagePng, [
	AC_DEFINE(HAVE_IMAGE_PNG)
	])
AC_CHECK_LIB(gd, gdImagePngEx, [
	AC_DEFINE(HAVE_GDIMAGEPNGEX)
	])
AC_CHECK_LIB(gd, gdImageJpeg, [
	AC_DEFINE(HAVE_IMAGE_JPEG)
	])
AC_CHECK_LIB(gd, gdImageStringTTF, [
	if test "$ac_have_libttf" = "yes"
	then
		AC_DEFINE(HAVE_GDIMAGESTRINGTTF)
	fi
	])
AC_CHECK_LIB(gd, gdImageStringFT, [
	if test "$ac_have_libfreetype" = "yes"
	then
		AC_DEFINE(HAVE_GDIMAGESTRINGFT)
	fi
	])
AC_CHECK_LIB(gd, gdImageFilledArc, [
	AC_DEFINE(HAVE_GDIMAGEFILLEDARC)
	])


AC_SUBST(LEXFLAGS)
AC_SUBST(INTTYPE)

AC_OUTPUT(Makefile)

echo "Configure done. Run 'make' to build CvsGraph"