dnl $QNS: configure.in,v 1.2 2001/12/18 18:33:35 bright Exp $

dnl Process this file with autoconf to produce a configure script.
AC_INIT(cvswrap.c)


dnl Yanked from screen.
define(AC_NOTE,
[echo "$1" 1>&AC_FD_MSG
])dnl

PROGRAM="cvswrap"
VERSION="0.9"
PACKAGE="${PROGRAM}-${VERSION}"
AC_NOTE(this is cvswrap version $VERSION)

AC_PREFIX_PROGRAM(cvswrap)

dnl Checks for programs.
AC_PROG_CC
AC_PROG_INSTALL

dnl Checks for libraries.
LIBOBJS=""
AC_SUBST(LIBOBJS)
PREFIX=$prefix
AC_SUBST(PREFIX)

dnl Checks for header files.
AC_HEADER_STDC
AC_HEADER_SYS_WAIT
AC_CHECK_HEADERS(sys/time.h unistd.h)

dnl Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_TYPE_PID_T
AC_TYPE_SIZE_T
AC_STRUCT_ST_BLKSIZE
AC_HEADER_TIME

AC_MSG_CHECKING(for if your compiler supports __func__)
AC_TRY_RUN([#include <string.h>
main()
{
	return(strcmp("main", __func__) == 0 ? 0 : 1);
}],[
	AC_MSG_RESULT(yes)
	func="__func__";
],[
	AC_MSG_RESULT(no)
])

if test "x$func" = "x" ; then
AC_MSG_CHECKING(for if your compiler supports __FUNCTION__)
AC_TRY_RUN([#include <string.h>
main()
{
	return(strcmp("main", __FUNCTION__) == 0 ? 0 : 1);
}],[
	AC_MSG_RESULT(yes)
	func="__FUNCTION__";
],[
	AC_MSG_RESULT(no)
])
fi

if test "x$func" = "x" ; then
	func="__FILE__";
fi

AC_DEFINE_UNQUOTED(FUNCDEF, $func)

AC_MSG_CHECKING(for specified path to real cvs(1))
HARD_PATH_REALCVS="/usr/bin/ncvs"
PATH_REALCVS=${HARD_PATH_REALCVS}
AC_ARG_WITH(real-cvs,
[  --with-real-cvs=path    where to expect the real cvs(1) binary to be ],
[ PATH_REALCVS="${withval}" ])
if test "x${PATH_REALCVS}" = "x${HARD_PATH_REALCVS}" ; then
	AC_MSG_RESULT(default: '${PATH_REALCVS}')
else
	AC_MSG_RESULT('${PATH_REALCVS}')
fi
AC_DEFINE_UNQUOTED(PATH_REALCVS, "${PATH_REALCVS}")

AC_DEFINE_UNQUOTED(SYSCONFDIR, $sysconfdir)

dnl Checks for library functions.
AC_CHECK_FUNCS(gettimeofday strcspn strdup strerror)

AC_CONFIG_HEADER(config.h)

AC_OUTPUT(Makefile)