dnl
dnl Configuring gauche-gl
dnl  process this file with "autoconf -I `gauche-config --ac`" to
dnl  generate 'configure'.
dnl $Id: configure.in,v 1.7 2004/11/10 18:11:59 mikiso Exp $
AC_PREREQ(2.54)
AC_INIT(Gauche-sdl, 0.5.1, mvess@michaelvess.com)
AC_GAUCHE_INIT_EXT
AC_CANONICAL_SYSTEM

AC_PATH_XTRA

# options for configure scripts
SDL_LIB="-lSDL"
AC_ARG_WITH(sdl, [  --with-sdl[=PATH]:      Use SDL library installed under PATH.
                          By default, Gauche-sdl assumes SDL is installed in
                          the system standard location.  If you do not want to
                          use SDL support, specify --with-sdl=no.], [
  case $with_sdl in
    no)  SDL_LIB= ;;
    yes) SDL_LIB="-lSDL";;
    *)   SDL_LIB="-lSDL"
         SDL_INCDIR="-I$with_sdl/include"
         SDL_LIBDIR="-L$with_sdl/lib";;
  esac
])

# Check for headers
AC_CHECK_HEADERS(SDL/SDL.h, , , [#include <SDL/SDL.h>])
AC_CHECK_HEADERS(SDL/SDL_framerate.h, [   # SDL_gfx
     HAVE_SDL_GFX=1
     SDL_GFX_LIB="-lSDL_gfx"
], ,)
AC_CHECK_HEADERS(SDL/SDL_image.h, [   # SDL_image
     HAVE_SDL_IMAGE=1
     SDL_IMAGE_LIB="-lSDL_image"
], ,)
AC_CHECK_HEADERS(SDL/SDL_mixer.h, [   # SDL_mixer
     HAVE_SDL_MIXER=1
     SDL_MIXER_LIB="-lSDL_mixer"
], ,)
AC_CHECK_HEADERS(SDL/SDL_ttf.h, [   # SDL_ttf
     HAVE_SDL_TTF=1
     SDL_TTF_LIB="-lSDL_ttf"
], ,)

AC_SUBST(SDL_LIB)
AC_SUBST(SDL_INCDIR)
AC_SUBST(SDL_LIBDIR)
AC_SUBST(HAVE_SDL_GFX)
AC_SUBST(SDL_GFX_LIB)
AC_SUBST(HAVE_SDL_IMAGE)
AC_SUBST(SDL_IMAGE_LIB)
AC_SUBST(HAVE_SDL_MIXER)
AC_SUBST(SDL_MIXER_LIB)
AC_SUBST(HAVE_SDL_TTF)
AC_SUBST(SDL_TTF_LIB)

# Sets the default value of INSTALL_TYPE macro.
AC_GAUCHE_INSTALL_TYPE(sys)

# Get compiler parameters which Gauche has been compiled with.
AC_GAUCHE_CC
AC_GAUCHE_FLAGS

# Check for other programs.
AC_PROG_INSTALL
AC_CHECK_PROGS(MAKEINFO, makeinfo)
AC_CHECK_PROGS(GZIP_PROGRAM, gzip)

# Check for libraries

# on cygwin, we need several extra -l flags.
case "$target" in
  *-*-cygwin*)
    CFLAGS="-DLIBGAUCHE_BODY $CFLAGS"
    LIBS="-lgauche -lgauche-uvector $LIBS"
    ;;
esac
AC_SUBST(GL_EXTRALIBS)
AC_SUBST(SDL_EXTRALIBS)

# Set LDFLAGS to generate shared library.
AC_GAUCHE_FIX_LIBS

# Output
AC_GAUCHE_EXT_FIXUP(src/sdl, gauche_sdl)
echo $PACKAGE_VERSION > VERSION
AC_OUTPUT(Makefile src/Makefile src/gfx/Makefile src/image/Makefile src/mixer/Makefile src/ttf/Makefile lib/Makefile lib/sdl/Makefile)