# Configure.in -*- m4 -*-
#
#  This file tests for various compiler features needed to configure 
#  the gconfmm package.  Original skeleton was provided by Stephan Kulow.
#  All tests were written by Tero Pulkkinen, Mirko Streckenbach, and 
#  Karl Nelson.
#
#  NOTE! IF YOU DO CHANGES HERE, CHECK IF YOU NEED TO MODIFY .m4 TOO!!!
#
#  Copyright 2001-2002 Free Software Foundation
#  Copyright 1999 gtkmm Development Team
#  Copyright 1998 Stephan Kulow 
#
AC_INIT(gconf/gconfmmconfig.h.in)

#########################################################################
#  Version and initialization
#########################################################################
GCONFMM_MAJOR_VERSION=2
GCONFMM_MINOR_VERSION=20
GCONFMM_MICRO_VERSION=0

#
# +1 : ? : +1  == new interface that does not break old one
# +1 : ? : 0   == new interface that breaks old one
#  ? : ? : 0   == no new interfaces, but breaks apps
#  ? :+1 : ?   == just some internal changes, nothing breaks but might work 
#                 better
# CURRENT : REVISION : AGE
GCONFMM_SO_VERSION=1:6:0

GCONFMM_VERSION=$GCONFMM_MAJOR_VERSION.$GCONFMM_MINOR_VERSION.$GCONFMM_MICRO_VERSION
GCONFMM_RELEASE=$GCONFMM_MAJOR_VERSION.$GCONFMM_MINOR_VERSION
AC_DEFINE_UNQUOTED(GCONFMM_MAJOR_VERSION, $GCONFMM_MAJOR_VERSION)
AC_DEFINE_UNQUOTED(GCONFMM_MINOR_VERSION, $GCONFMM_MINOR_VERSION)
AC_DEFINE_UNQUOTED(GCONFMM_MICRO_VERSION, $GCONFMM_MICRO_VERSION)
AC_SUBST(GCONFMM_VERSION)
AC_SUBST(GCONFMM_RELEASE)
AC_SUBST(GCONFMM_SO_VERSION)

AC_CONFIG_AUX_DIR(scripts)

dnl For automake.
VERSION=$GCONFMM_VERSION
PACKAGE=gconfmm

dnl Initialize automake stuff
AM_INIT_AUTOMAKE($PACKAGE, $VERSION)

dnl Specify a configuration file (no autoheader)
AM_CONFIG_HEADER(gconf/gconfmmconfig.h)
AM_MAINTAINER_MODE
AL_ACLOCAL_INCLUDE(scripts)


#########################################################################
#  Configure arguments 
#########################################################################

#########################################################################
#  Environment Checks
#########################################################################
AC_PROG_CC
AC_PROG_CPP
AC_PROG_MAKE_SET
AC_CANONICAL_HOST
AM_DISABLE_STATIC
AM_PROG_LIBTOOL

AL_PROG_GNU_M4(AC_MSG_ERROR([dnl
SUN m4 does not work for building gtkmm. 
Please install GNU m4.]))

AL_PROG_GNU_MAKE(AC_MSG_ERROR([dnl
SUN make does not work for building gtkmm.
Please install GNU make.]))


#########################################################################
#  Dependancy checks
#########################################################################

# Make these available to both PKG_CHECK_MODULES and the .pc.in file:
GLIBMM_VERSION_NEEDED=2.6.4
AC_SUBST(GLIBMM_VERSION_NEEDED)
GTKMM_VERSION_NEEDED=2.4.0
AC_SUBST(GTKMM_VERSION_NEEDED)
GCONF_VERSION_NEEDED=2.4.0
AC_SUBST(GCONF_VERSION_NEEDED)

PKG_CHECK_MODULES(GCONFMM, glibmm-2.4 >= $GLIBMM_VERSION_NEEDED gconf-2.0 >= $GCONF_VERSION_NEEDED)
AC_SUBST(GCONFMM_CFLAGS)
AC_SUBST(GCONFMM_LIBS)

PKG_CHECK_MODULES(GCONFMM_EXAMPLES, gtkmm-2.4 >= $GTKMM_VERSION_NEEDED gconf-2.0 >= $GCONF_VERSION_NEEDED)
AC_SUBST(GCONFMM_EXAMPLES_CFLAGS)
AC_SUBST(GCONFMM_EXAMPLES_LIBS)

GLIBMM_LIBDIR=`pkg-config --variable=libdir glibmm-2.4`
GMM_PROCDIR=$GLIBMM_LIBDIR/glibmm-2.4/proc
AC_SUBST(GMM_PROCDIR)
GMM_PROC=$GMM_PROCDIR/gmmproc
AC_SUBST(GMM_PROC)

#########################################################################
#  C++ checks
#########################################################################
AC_PROG_CXX
AC_LANG_CPLUSPLUS


# Create a list of input directories for Doxygen.  We have to check wether
# we are building in the source directory, because Doxygen doesn't like
# duplicated directories in the input list.
GCONFMM_DOXYGEN_INPUT=''
gtkmm_srcdir=`cd "$srcdir" && pwd`
gtkmm_builddir=`pwd`
for sublib in gconf
do
  GCONFMM_DOXYGEN_INPUT="$GCONFMM_DOXYGEN_INPUT $gtkmm_builddir/$sublib/$sublib""mm/"
  test "x$gtkmm_builddir" = "x$gtkmm_srcdir" || \
    GCONFMM_DOXYGEN_INPUT="$GCONFMM_DOXYGEN_INPUT $gtkmm_srcdir/$sublib/$sublib""mm/"
done
AC_SUBST(GCONFMM_DOXYGEN_INPUT)



# Dummy conditional just to make automake-1.4 happy.
# We need an always-false condition in docs/Makefile.am.
AM_CONDITIONAL(GCONFMM_FALSE,[false])

# HACK:  Assign a dummy in order to prevent execution of autoheader by the
# maintainer-mode rules.  That would fail since we aren't using autoheader.
AUTOHEADER=':'


AC_OUTPUT([
  Makefile

  gconf/Makefile
  gconf/gconfmm-2.6.pc
  gconf/gconfmm-2.6-uninstalled.pc
  gconf/src/Makefile
  gconf/gconfmm/Makefile
  gconf/gconfmm/private/Makefile
        gconfmm.spec

  tools/Makefile
  tools/m4/Makefile
  tools/extra_defs_gen/Makefile

  scripts/Makefile

  examples/Makefile
    examples/client/Makefile

    docs/Makefile
    docs/reference/Makefile
    docs/reference/Doxyfile
])