m4_define([guiloader_cpp_version], [2.10.0])
m4_define([guiloader_cpp_prerelease], [0])
m4_define([guiloader_cpp_dep_guiloader], [2.10.0])
m4_define([guiloader_cpp_dep_gtkmm], [2.10.0])

m4_define([guiloader_cpp_timestamp], m4_substr(m4_esyscmd([date +%Y%m%d%H%M]), [0], [12])))
m4_define([guiloader_cpp_package], m4_if(m4_eval(guiloader_cpp_prerelease), [0], guiloader_cpp_version, guiloader_cpp_version[-]guiloader_cpp_timestamp))
m4_define([guiloader_cpp_release], m4_if(m4_eval(guiloader_cpp_prerelease), [0], [0.1], [0.0.]guiloader_cpp_timestamp))

AC_INIT([guiloader-c++], [guiloader_cpp_package], [maxim_udushlivy@users.sourceforge.net], [guiloader-c++])
AC_CONFIG_HEADERS([config.h])
AM_INIT_AUTOMAKE([-Wall -Werror no-dist-gzip dist-bzip2 foreign])

GUILOADER_CPP_VERSION=guiloader_cpp_version
GUILOADER_CPP_RELEASE=guiloader_cpp_release
GUILOADER_CPP_PACKAGE=guiloader_cpp_package
GUILOADER_CPP_DEP_GUILOADER=guiloader_cpp_dep_guiloader
GUILOADER_CPP_DEP_GTKMM=guiloader_cpp_dep_gtkmm

AC_PROG_CXX
AC_LANG_CPLUSPLUS

AC_DISABLE_STATIC
AC_LIBTOOL_WIN32_DLL
AC_PROG_LIBTOOL

AC_ARG_ENABLE(
	[hiddenvisibility],
	[AS_HELP_STRING([--enable-hiddenvisibility], [use -fvisibility=hidden GCC flag])],
	[enable_hiddenvisibility=yes], [enable_hiddenvisibility=no]
)

if test "$enable_hiddenvisibility" = yes; then
	GUILOADER_CPP_CFLAGS="-fvisibility=hidden"
else
	GUILOADER_CPP_CFLAGS=""
fi

DEP_PKGS="guiloader >= $GUILOADER_CPP_DEP_GUILOADER gtkmm-2.4 >= $GUILOADER_CPP_DEP_GTKMM"

PKG_CHECK_MODULES([PKGS], $DEP_PKGS)

AC_SUBST([GUILOADER_CPP_VERSION])
AC_SUBST([GUILOADER_CPP_RELEASE])
AC_SUBST([GUILOADER_CPP_PACKAGE])
AC_SUBST([GUILOADER_CPP_DEP_GUILOADER])
AC_SUBST([GUILOADER_CPP_DEP_GTKMM])
AC_SUBST([PKGS_CFLAGS])
AC_SUBST([PKGS_LIBS])
AC_SUBST([GUILOADER_CPP_CFLAGS])
AC_SUBST([DEP_PKGS])

AC_CONFIG_FILES([
	Makefile
	guiloader-c++.spec
		guiloader-c++/Makefile
		guiloader-c++/guiloader-c++.pc
		examples/Makefile
			examples/simple/Makefile
			examples/typical/Makefile
])

AC_OUTPUT