m4_define([guiloader_version], [2.10.0])
m4_define([guiloader_prerelease], [0])
m4_define([guiloader_dep_glib], [2.12.0])
m4_define([guiloader_dep_gtk], [2.10.0])

m4_define([guiloader_timestamp], m4_substr(m4_esyscmd([date +%Y%m%d%H%M]), [0], [12])))
m4_define([guiloader_package], m4_if(m4_eval(guiloader_prerelease), [0], guiloader_version, guiloader_version[-]guiloader_timestamp))
m4_define([guiloader_release], m4_if(m4_eval(guiloader_prerelease), [0], [0.1], [0.0.]guiloader_timestamp))

AC_INIT([guiloader], [guiloader_package], [maxim_udushlivy@users.sourceforge.net], [guiloader])
AC_CONFIG_HEADERS([config.h])
AM_INIT_AUTOMAKE([-Wall -Werror no-dist-gzip dist-bzip2 foreign])

GUILOADER_VERSION=guiloader_version
GUILOADER_RELEASE=guiloader_release
GUILOADER_PACKAGE=guiloader_package
GUILOADER_DEP_GLIB=guiloader_dep_glib
GUILOADER_DEP_GTK=guiloader_dep_gtk

AC_PROG_CC
AC_LANG_C

AC_DISABLE_STATIC
AC_LIBTOOL_WIN32_DLL
AC_PROG_LIBTOOL

AC_ARG_ENABLE(
	[hiddenvisibility],
	[AS_HELP_STRING([--enable-hiddenvisibility], [use -fvisibility=hidden GCC flag])],
	[enable_hiddenvisibility=yes], [enable_hiddenvisibility=no]
)

if test "$enable_hiddenvisibility" = yes; then
	GUILOADER_CFLAGS="-fvisibility=hidden"
else
	GUILOADER_CFLAGS=""
fi

DEP_PKGS="glib-2.0 >= $GUILOADER_DEP_GLIB gtk+-2.0 >= $GUILOADER_DEP_GTK"

PKG_CHECK_MODULES([PKGS], $DEP_PKGS)

AC_SUBST([GUILOADER_VERSION])
AC_SUBST([GUILOADER_RELEASE])
AC_SUBST([GUILOADER_PACKAGE])
AC_SUBST([GUILOADER_DEP_GLIB])
AC_SUBST([GUILOADER_DEP_GTK])
AC_SUBST([PKGS_CFLAGS])
AC_SUBST([PKGS_LIBS])
AC_SUBST([GUILOADER_CFLAGS])
AC_SUBST([DEP_PKGS])

AC_CONFIG_FILES([
	Makefile
	guiloader.spec
		guiloader/Makefile
		guiloader/guiloader.pc
		examples/Makefile
			examples/simple/Makefile
			examples/typical/Makefile
])

AC_OUTPUT