#!/usr/bin/kaptain
#
# curl grammar (C) 2000 by Schneelocke, Schneelocke@gmx.net 
# released under the GNU General Public license, version 2
# http://www.fsf.org/copyleft/gpl.txt
#

start "cURL" -> filespec url buttons ;
buttons :horizontal -> @action(command)="OK" @button(opt)="Options" @close="Cancel" ;

command :framed -> "curl " opt filespec url ;

opt "Options" -> options @close="Close" ;
options :framed :tabbed -> optc opthf ;

optc :horizontal "Common options" -> optcommon optcommon2 optcommon3 ;
opthf :horizontal "HTTP/FTP options" -> opthttp opthttp2 optftp ; 

optcommon -> norc dump gethead configf maxt netrc nobuf ;
optcommon2 -> rang sil verb write proxy request progress ;
optcommon3 -> speedlim timecon ssl stder ; 
opthttp -> ag cook cont dat ref ;
opthttp2 -> cert fail for sethead inc loc app ;
optftp -> useasc list ftpp quot ; 

app -> append | ! @ ;
append "Append FTP uloads" -> "--append " ;

ag -> agent | ! @ ;
agent "Set User Agent to" -> "--user-agent " @string="Mozilla/4.0" " " ;

cook -> cookie | ! @ ;
cookie "Pass cookie(s)" -> "--cookie " @string="name1=value1;name2=value2;..." " " ;

useasc -> useascii | ! @ ;
useascii "Use ASCII for FTP gets and LDAP info" -> "--use-ascii " ;

cont -> conti | ! @ ;
conti "Continue HTTP/1.1 transfers" -> ! continue | continueat ; 
continue "Where previously stopped" -> "--continue " ;
continueat "At offset" -> "--continue-at " @integer " " ;

dat -> data | ! @ ;
data "POST data" -> "--data " @string " " ;

dump -> dumpheader | ! @ ;
dumpheader "Write HTTP header/FTP info to file" -> "--dump-header " @outfile " " ;

ref -> referrer | ! @ ;
referrer "Set Referrer Page to" -> "--referer " @string="http://host.domain/directory/page.html" " " ;

cert -> certificate | ! @ ;
certificate "Use PEM certificate file for HTTPS" -> "--cert " @infile " " ;

fail -> failsilently | ! @ ;
failsilently "Fail silently on server errors" -> "--fail " ;

for -> form | ! @ ;
form "POST form data" -> "--form " @string " " ;

sethead -> setheader | ! @ ;
setheader "Set custom HTTP header" -> "--header " @string " " ;

inc -> include | ! @ ;
include "Include HTTP header in output" -> "--include " ;

gethead -> getheader | ! @ ;
getheader "Fetch HTTP header / FTP file size only" -> "--head " ;

configf -> configfile | ! @ ;
configfile "File to read arguments from" -> "--config " @infile " " ;

list -> listonly | ! @ ;
listonly "Filename only for FTP listings" -> "--list-only " ;

loc -> location | ! @ ;
location "Honor HTTP Location: headers" -> "--location " ;

maxt -> maxtime | ! @ ;
maxtime "Maximum allowed running time (sec.)" -> "--maxtime " mtime " " ;
mtime -> @integer(1,32767)=1800 ;

netrc -> netrcfile | ! @ ;
netrcfile "Use .netrc file for account info" -> "--netrc " ;

nobuf -> nobuffer | ! @ ;
nobuffer "Disable output buffering" -> "--no-buffer " ;

ftpp -> ftpport | ! @ ;
ftpport "Use PORT instead of PASV" -> "--ftpport " ftppaddress " " ;
ftppaddress -> interface | ip | hostname | !default ;
interface "Interface name" -> @string="eth0" ;
ip "IP address" -> @string ;
hostname "Hostname" -> @string ;
default "Machine's default" -> "-" ;

norc -> nocurlrc | ! @ ;
nocurlrc "Don't read ~/.curlrc" -> "-q " ;

quot -> quote | ! @ ;
quote "Send arbitrary FTP command" -> "--quote " @string " " ;

rang -> range | ! @ ;
range "Specify byte range" -> "--range " @string " " ;

sil -> silent | ! @ ;
silent "Silent mode" -> "--silent " showerrors " " ;
showerrors -> ! showerr | dontshowerr ;
showerr "Show errors" -> "-S " ;
dontshowerr "Don't show errors" -> " " ;

filespec :framed -> ! outfile | infile ;

outfile "Download" -> outputfile | !remotename ;
outputfile "file" -> "--output " @outfile " " ;
remotename "Use remote file name" -> "--remote-name " ;

infile "Upload" -> "--upload-file " @infile " " ;

userinf -> userinfo | ! @ ;
userinfo "Specify user:password" -> "--user " @string " " ;

proxyinf -> proxyinfo | ! @ ;
proxyinfo "Specify user:password for proxy" -> "--proxy-user" @string " " ;

verb -> verbose | ! @ ;
verbose "Verbose mode" -> "--verbose " ;

write -> writeout | ! @ ;
writeout "Writeout format" -> "--write-out " @string " " ;
writeoutformat -> @string ;

proxy -> useproxy | ! @ ;
useproxy "Use proxy" -> "--proxy " @string="host:port" " " ;

request -> crequest | ! @ ;
crequest "Use this request instead of GET/LIST" -> "--request " @string " " ;

speedlim -> speedlimit | ! @ ;
speedlimit "Speed minimum" -> " --speed-limit " speedbytes " --speed-time " speedtime " ";
speedbytes "at least ___ bytes" -> @integer=30 ;
speedtime "per ___ seconds" -> @integer=1 ;

timecon -> timecond | ! @ ;
timecond "document time/date" -> "--time-cond " @string " " ;

ssl "SSL version" -> force2 | force3 | !either ;
force2 "force use of SSLv2" -> "--sslv2 " ;
force3 "force use of SSLv3" -> "--sslv3 " ;
either "allow both" -> " " ;

progress -> progressbar | ! @ ;
progressbar "display progress bar" -> "--progress-bar " ;

crlf -> convertcrlf | ! @ ;
convertcrlf "Convert CR/LF in uploads" -> "--crlf " ;

stder -> stderr | ! @ ;
stderr "Redirect stderr to file" -> "--stderr " @outfile " " ;

url "URL" -> @string ;
 