#!/usr/bin/kaptain
#
# nslookup grammar (C) 2000 by Schneelocke, Schneelocke@gmx.net 
# released under the GNU General Public license, version 2
# http://www.fsf.org/copyleft/gpl.txt
#

start "nslookup" -> ui buttons ;
ui :framed -> options server hosttofind ;
buttons:horizontal -> @action(command)="OK" @button(qopt)="Query options" @close="Cancel";

command -> "nslookup " options qoptions hosttofind " " server ;

options :horizontal "Options" -> opt1 opt2 ;
opt1 -> domain defname search port recurse ;
opt2 -> retries root timeout ignoretc vc debugmode ;
qopt "Query options" -> qoptions @close="OK" ;
qoptions :framed -> selectclass querytype ;

selectclass "Query class" -> in | chaos | hesiod | ! classany ;
in "Internet" -> "-class=in " ;
chaos "Chaos" -> "-class=chaos " ;
hesiod "MIT Athena Hesiod" -> "-class=hesiod " ;
classany "Any" -> "-class=any " ;

debugmode -> enabledebug | ! @ ;
enabledebug "Enable debugging" -> ! normaldebug | alldebug ;
normaldebug "Standard debug output" -> "-debug " ;
alldebug "Exhaustive debug output" -> "-debug -d2 " ;

domain -> domains | ! @ ;
domains "Default domain names" -> ! setdomain | searchlist ;
setdomain "Set default domain name only" -> "-domain=" domainname " " ;
domainname -> @string ;
searchlist "Set default domain name and searchlist" -> "-srchlist=" srchlist " " ;
srchlist -> @string="name1/.../name6" ;

defname -> nodefname | ! @ ;
nodefname "Don't append default domain name to single-component lookup request" -> "-nodefname " ;

search -> nosearch | ! @ ;
nosearch "Never append domain names from domain search list" -> "-nosearch" ;

port -> setport | ! @ ;
setport "Use TCP/UDP port" -> "-port=" porttouse " ";
porttouse -> @integer=53 ;

querytype "Query for" -> a | cname | hinfo | minfo | mx | ns | ptr | soa | txt | uinfo | wks | ! any | axfr | mb | md | mf | null ;
a "Internet address" -> "-type=a " ;
cname "Canonical name for an alias" -> "-type=cname " ;
hinfo "CPU and OS type" -> "-type=hinfo " ;
minfo "Mailbox or mail list information" -> "-type=minfo " ;
mx "Mail exchanger" -> "-type=mx " ;
ns "Name server for the named zone" -> "-type=ns " ;
ptr "Host name/other information" -> "-type=ptr " ;
soa "State of Authority" -> "-type=soa " ;
txt "Text information" -> "-type=txt " ;
uinfo "User information" -> "-type=uinfo " ;
wks "Well-known Services supported" -> "-type=wks " ;
any "Any" -> "-type=any " ;
axfr "AXFR (cf. RFC 1035)" -> "-type=axfr " ;
mb "MB (cf. RFC 1035)" -> "-type=mb " ;
md "MD (cf. RFC 1035)" -> "-type=md " ;
mf "MF (cf. RFC 1035)" -> "-type=mf " ;
null "NULL (cf. RFC 1035)" -> "-type=null " ;

recurse -> norecurse | ! @ ;
norecurse "Instruct name server not to query other servers" -> "-norecurse " ;

retries -> setretries | ! @ ;
setretries "Set number of retries" -> "-retry=" numberofretries " " ;
numberofretries -> @integer=4 ;

root -> setroot | ! @ ;
setroot "Change the name of the root server" -> "-root=" roothost " " ;
roothost -> @string="ns.internic.net" ;

timeout -> settimeout | ! @ ;
settimeout "Set timeout interval to ___ seconds" -> "-timeout=" timeoutsec " " ;
timeoutsec -> @integer=5 ;

vc -> virtualcircuit | ! @ ;
virtualcircuit "Always use virtual circuit when sending requests" -> "-vc " ;

ignoretc -> doignoretc | ! @ ;
doignoretc "Ignore packet truncation errors" -> "-ignoretc " ;

hosttofind "Host to look for" -> @string ;

server "Server" -> setserver | ! @ ;
setserver "Specify server to use" -> "-" servername ;
servername -> @string ; 
 