#!/usr/bin/kaptain
#
# ping grammar (C) 2000 by Schneelocke, Schneelocke@gmx.net 
# released under the GNU General Public license, version 2
# http://www.fsf.org/copyleft/gpl.txt
#
start "Ping" -> command buttons ;

buttons :horizontal -> @action(command)="OK" @close="Cancel" ;
command :framed -> "ping " opt outp type host ;

opt :framed :horizontal "Ping options" -> opt1 opt2 ;

opt1 "Options" -> coun dontfrag sodeb interf pre num pad ; 
opt2 "More options" -> recroute noroute packsize tos ttl maxwai noloo ;

outp "Output" -> output | ! @ ;
output "Specify output type" -> ! verbose | quiet ;

verbose "Verbose" -> "-v " ;
quiet "Quiet" -> "-q " ;

type "Ping type" -> flood | wait | !normal ;

coun -> count | ! @ ;
count "Maximum # of packets to transmit" -> "-c " countcount " ";
countcount -> @integer=10 ;

dontfrag -> dontfragment | ! @ ;
dontfragment "Don't fragment packets" -> "-D " ;

sodeb -> sodebug | ! @ ;
sodebug "Set SO_DEBUG on the socket used" -> "-d " ;

interf -> interface | ! @ ;
interface "Specify interface address to use" -> "-I " ifaddr " ";
ifaddr -> @string ;

pre -> preload | ! @ ;
preload "# of packets to spew out as fast as possible (root only)" -> "-l " preloadcount " " ;
preloadcount -> @integer ;

num -> numeric | ! @ ;
numeric "Don't look up hostnames" -> "-n " ;

pad -> padding | ! @ ;
padding "Specify pad bytes (up to 16)" -> "-p " padpattern " " ;
padpattern -> @string="ff" ;

recroute -> recordroute | ! @ ;
recordroute "Try to record route (may not work!)" -> "-R " ;

noroute -> norouting | ! @ ;
norouting "Bypass routing tables (works only on directly-attached networks!" -> "-r " ;

packsize -> packetsize | ! @ ;
packetsize "Specify number of data bytes in ICMP packet" -> "-s " packetbytes " " ;
packetbytes -> @integer=56  ;

tos -> typeos | ! @ ;
typeos "Specify type of service" -> "-T " typeofservice " " ;
typeofservice -> @integer ;

ttl -> timetl | ! @ ;
timetl "Specify time-to-live" -> "-t " timetolive " " ;
timetolive -> @integer=30 ;

maxwai -> maxwait | ! @ ;
maxwait "Specify # of seconds to wait for response to a packet" -> "-w " maxwaittime " " ;
maxwaittime -> @integer=10 ;

noloo -> noloop | ! @ ;
noloop "Disable loopback for multicast pings" -> "-L " ;

flood "Flood ping (root only)" -> "-f " ;

wait "Send individual packets with specified delay" -> "-i " waitsec ;
waitsec "# of seconds to wait" -> @integer=5 ;

normal "Normal ping" -> " " ;

host "Address to ping" -> @string ;
 