#!/usr/bin/kaptain
#
# weblint grammar (C) 2000 by Schneelocke, Schneelocke@gmx.net 
# released under the GNU General Public license, version 2
# http://www.fsf.org/copyleft/gpl.txt
#
# weblint: http://www.weblint.org
#

start "weblint" -> command buttons;
buttons:horizontal -> @action(command)="OK" @close="Cancel";

command :framed  -> "weblint " opt mode files ;

opt "Options" -> disid enid conf stderr ;

disid -> disableid | ! @ ;
disableid "Disable these identifiers" -> "-d " dislist " " ;
dislist -> @string ;

enid -> enableid | ! @ ;
enableid "Enable these identifiers" -> "-e " enlist " " ;
enlist -> @string ;

conf -> config | ! @ ;
config "Use configuration file" -> "-f " conffile " " ;
conffile -> @infile ;

stderr -> usestderr | ! @ ;
usestderr "Print to STDERR rather than STDOUT" -> "-stderr " ;

mode "Mode of operation" -> listmesg | ! unfluff ;

listmesg "List known identifiers/messages" -> "-message " ;
unfluff "Pick fluff off of HTML file(s)" -> nocase nosym pedantic short terse ;

nocase -> ignorecase | ! @ ;
ignorecase "Ignore case of element tags" -> "-i " ;

nosym -> nosymlinks | ! @ ;
nosymlinks "Don't unfluff symlinks" -> "-l " ;

pedantic -> pedanticmode | ! @ ;
pedanticmode "Pedantic mode" -> "-pedantic " ;

short -> shortmesg | ! @ ;
shortmesg "No filename in messages" -> "-s " ;

terse -> tersemode | ! @ ;
tersemode "Terse output mode" -> "-t " ;

files "File(s) to check" -> @infile ;
 