# Configure.in -*- m4 -*-
#
#  This file tests for various compiler features needed to configure 
#  the libbonobomm package.  Original skeleton was provided by Stephan Kulow.
#  All tests were written by Tero Pulkkinen, Mirko Streckenbach, and
#  Karl Nelson.
#
#  NOTE! IF YOU DO CHANGES HERE, CHECK IF YOU NEED TO MODIFY .m4 TOO!!!
#
#  Copyright 2001-2002 Free Software Foundation
#  Copyright 1999 gtkmm Development Team
#  Copyright 1998 Stephan Kulow
#
AC_INIT(bonobomm/libbonobommconfig.h.in)

#########################################################################
#  Version and initialization
#########################################################################
LIBBONOBOMM_MAJOR_VERSION=1
LIBBONOBOMM_MINOR_VERSION=3
LIBBONOBOMM_MICRO_VERSION=8

#
# +1 : ? : +1  == new interface that does not break old one
# +1 : ? : 0   == new interface that breaks old one
#  ? : ? : 0   == no new interfaces, but breaks apps
#  ? :+1 : ?   == just some internal changes, nothing breaks but might work
#                 better
# CURRENT : REVISION : AGE
LIBBONOBOMM_SO_VERSION=9:0:0

LIBBONOBOMM_VERSION=$LIBBONOBOMM_MAJOR_VERSION.$LIBBONOBOMM_MINOR_VERSION.$LIBBONOBOMM_MICRO_VERSION
LIBBONOBOMM_RELEASE=$LIBBONOBOMM_MAJOR_VERSION.$LIBBONOBOMM_MINOR_VERSION
AC_DEFINE_UNQUOTED(LIBBONOBOMM_MAJOR_VERSION, $LIBBONOBOMM_MAJOR_VERSION)
AC_DEFINE_UNQUOTED(LIBBONOBOMM_MINOR_VERSION, $LIBBONOBOMM_MINOR_VERSION)
AC_DEFINE_UNQUOTED(LIBBONOBOMM_MICRO_VERSION, $LIBBONOBOMM_MICRO_VERSION)
AC_SUBST(LIBBONOBOMM_VERSION)
AC_SUBST(LIBBONOBOMM_RELEASE)
AC_SUBST(LIBBONOBOMM_SO_VERSION)

AC_CONFIG_AUX_DIR(scripts)

dnl For automake.
VERSION=$LIBBONOBOMM_VERSION
PACKAGE=libbonobomm

dnl Initialize automake stuff
AM_INIT_AUTOMAKE($PACKAGE, $VERSION)

dnl Specify a configuration file (no autoheader)
AM_CONFIG_HEADER(bonobomm/libbonobommconfig.h)
AM_MAINTAINER_MODE
AL_ACLOCAL_INCLUDE(scripts)


#########################################################################
#  Configure arguments
#########################################################################

#########################################################################
#  Environment Checks
#########################################################################
AC_PROG_CC
AC_PROG_CPP
AC_PROG_MAKE_SET
AC_CANONICAL_HOST
AM_DISABLE_STATIC
AM_PROG_LIBTOOL

AL_PROG_GNU_M4(AC_MSG_ERROR([dnl
SUN m4 does not work for building gtkmm.
Please install GNU m4.]))

AL_PROG_GNU_MAKE(AC_MSG_ERROR([dnl
SUN make does not work for building gtkmm.
Please install GNU make.]))


#########################################################################
#  Dependancy checks
#########################################################################

# Make these available to both PKG_CHECK_MODULES and the .pc.in file:
GTKMM_VERSION_NEEDED=2.0.0
AC_SUBST(GTKMM_VERSION_NEEDED)
LIBBONOBO_VERSION_NEEDED=2.0.0
AC_SUBST(LIBBONOBO_VERSION_NEEDED)
ORBITCPP_VERSION_NEEDED=1.3.8
AC_SUBST(ORBITCPP_VERSION_NEEDED)

PKG_CHECK_MODULES(LIBBONOBOMM, gtkmm-2.0 >= $GTKMM_VERSION_NEEDED libbonobo-2.0 >= $LIBBONOBO_VERSION_NEEDED ORBit-2.0-cpp >= $ORBITCPP_VERSION_NEEDED)
AC_SUBST(LIBBONOBOMM_CFLAGS)
AC_SUBST(LIBBONOBOMM_LIBS)

# orbit-idl
ORBIT_IDL="`pkg-config --variable=orbit_idl ORBit-2.0`"
AC_SUBST(ORBIT_IDL)

# Get idl locations:
IDLDIR_LIBBONOBO="`pkg-config --variable=idldir libbonobo-2.0`"
AC_SUBST(IDLDIR_LIBBONOBO)
IDLDIR_BONOBO_ACTIVATION="`pkg-config --variable=idldir bonobo-activation-2.0`"
IDL_CFLAGS_BONOBO="-I/$IDLDIR_LIBBONOBO -I/$IDLDIR_BONOBO_ACTIVATION"
AC_SUBST(IDL_CFLAGS_BONOBO)

GTKMM_PREFIX=`pkg-config --variable=prefix gtkmm-2.0`
GTKMM_PROCDIR=$GTKMM_PREFIX/lib/gtkmm-2.0/proc
AC_SUBST(GTKMM_PROCDIR)
GTKMM_PROC=$GTKMM_PROCDIR/gtkmmproc
AC_SUBST(GTKMM_PROC)

#########################################################################
#  C++ checks
#########################################################################
AC_PROG_CXX
AC_LANG_CPLUSPLUS


# Dummy conditional just to make automake-1.4 happy.
# We need an always-false condition in docs/Makefile.am.
AM_CONDITIONAL(LIBBONOBOMM_FALSE,[false])

# HACK:  Assign a dummy in order to prevent execution of autoheader by the
# maintainer-mode rules.  That would fail since we aren't using autoheader.
AUTOHEADER=':'


AC_OUTPUT([
  Makefile
  libbonobomm-2.0.pc
  libbonobomm-2.0-uninstalled.pc

  bonobomm/Makefile
    bonobomm/generated/Makefile
    bonobomm/servers/Makefile
      bonobomm/servers/private/Makefile
    bonobomm/servers_src/Makefile
  tools/Makefile
    tools/m4/Makefile
    tools/extra_defs_gen/Makefile

  scripts/Makefile
])