awk '
BEGIN{
		if(ARGC < 2)
			exit
}

/^$/{
		next;
}
/^#/{
		next;
}
collect && /^[^ \t]/{
		collect = 0;
}
collect && section ~ "dev"{
		dev[ndev++] = $1;
}
collect && section ~ "link"{
		link[nlink++] = $1;
}
collect && section ~ "mod"{
		mod[nmod++] = $1;
}
$0 ~ /^[^ \t]/{
		if($0 ~ "(dev|link|mod)"){
			section = $0;
			collect = 1;
		}
		next;
}

END{
		if(ARGC < 2)
			exit "usage"

		printf "#include \"u.h\"\n"
		printf "#include \"libc.h\"\n"
		printf "#include \"libns.h\"\n"
		printf "\n"

		for(i = 0; i < ndev; i++)
			printf "extern Dev %sdevtab;\n", dev[i];
		printf "Dev* devtab[]={\n"
		for(i = 0; i < ndev; i++)
			printf "\t&%sdevtab,\n", dev[i];
		printf "\tnil,\n};\n\n";


		for(i = 0; i < nlink; i++)
			printf "extern void %slink(void);\n", link[i];

		printf "void links(void){\n";
		for(i = 0; i < nlink; i++)
			printf "\t%slink();\n", link[i];
		printf "}\n\n";

		printf "void modinit(void){\n";
		for(i = 0; i < nmod; i++)
			printf "\t%smodinit();\n", mod[i];
		printf "}\n\n";

		printf "char* conffile = \"%s\";\n", ARGV[1];
#		printf "ulong kerndate = KERNDATE;\n";

		exit
}' $* | sed 's/
//'