AC_PREREQ(2.57)
AC_COPYRIGHT([(c) Copyright 2003-2005 Matt Messier, John Viega])
AC_INIT([xxl], [1.0.1], [xxl@zork.org])
AM_INIT_AUTOMAKE([1.7 foreign])
AM_CONFIG_HEADER([config.h xxl.h])
AC_CONFIG_SRCDIR([xxl.h.in])
AC_CONFIG_AUX_DIR(.)
AC_PREFIX_DEFAULT([/usr/local])

XXL_VERSION_CURRENT=2
XXL_VERSION_REVISION=0
XXL_VERSION_AGE=1

AC_SUBST(XXL_VERSION_CURRENT)
AC_SUBST(XXL_VERSION_REVISION)
AC_SUBST(XXL_VERSION_AGE)

AC_ARG_WITH([threads], [  --without-threads       disable the use of threads],
        [USE_THREADS="$withval"], [USE_THREADS="yes"])
if test "$USE_THREADS" = "no"; then
    AC_DEFINE(XXL_WITHOUT_THREADS,1,[Define this to disable the use of threads.])
fi

AC_ARG_ENABLE([debug], [  --enable-debug          build with debugging code enabled],
        [if test "$enablevar" != "no"; then
            AC_MSG_NOTICE([Building with debugging code enabled.])
            CFLAGS="$CFLAGS -g"
            CPPFLAGS="$CPPFLAGS -D_DEBUG"
        fi])

AC_PROG_CC
AC_PROG_LIBTOOL
AC_SUBST(LIBTOOL_DEPS)

if test "$USE_THREADS" != "no"; then
    ACX_PTHREAD
    CC="$PTHREAD_CC"
    LIBS="$LIBS $PTHREAD_LIBS"
    CFLAGS="$CFLAGS $PTHREAD_CFLAGS"
    AC_CHECK_HEADERS(pthread.h)
fi

AC_HEADER_STDC
AC_CHECK_HEADERS(fcntl.h setjmp.h)
AC_CHECK_HEADERS(sys/types.h sys/socket.h)

AC_C_CONST

if test "$GCC" = "yes"; then
    CFLAGS="$CFLAGS -Wall"
fi

AC_CONFIG_FILES([Makefile], [chmod -w Makefile])
AC_OUTPUT