dnl Process this file with autoconf to produce a configure script.
AC_INIT(src/sdlmm.h)

dnl Automake / package stuff
# We want an absolute path to the source-dir.
case "$srcdir" in
    /*)
    ;;
    *)
	oldsrcdir="$srcdir"
	srcdir="`cd \"$srcdir\";pwd`"
	AC_MSG_WARN([ Converted $oldsrcdir to $srcdir,
If this does not work, please use an absolute path to the configure script. ])
    ;;
esac

#
# Making releases:
#   MICRO_VERSION += 1;
#   INTERFACE_AGE += 1;
#   BINARY_AGE += 1;
# if any functions have been added, set INTERFACE_AGE to 0.
# if backwards compatibility has been broken,
# set BINARY_AGE and INTERFACE_AGE to 0.
#
MAJOR_VERSION=0
MINOR_VERSION=1
MICRO_VERSION=8
INTERFACE_AGE=0
BINARY_AGE=0
VERSION=$MAJOR_VERSION.$MINOR_VERSION.$MICRO_VERSION
export VERSION

AC_SUBST(MAJOR_VERSION)
AC_SUBST(MINOR_VERSION)
AC_SUBST(MICRO_VERSION)
AC_SUBST(INTERFACE_AGE)
AC_SUBST(BINARY_AGE)
AC_SUBST(VERSION)

# libtool versioning
LT_RELEASE=$MAJOR_VERSION.$MINOR_VERSION
LT_CURRENT=`expr $MICRO_VERSION - $INTERFACE_AGE`
LT_REVISION=$INTERFACE_AGE
LT_AGE=`expr $BINARY_AGE - $INTERFACE_AGE`

AC_SUBST(LT_RELEASE)
AC_SUBST(LT_CURRENT)
AC_SUBST(LT_REVISION)
AC_SUBST(LT_AGE)

AM_CONFIG_HEADER(src/sdlmm_autoconfig.h)
AC_CANONICAL_HOST
AC_CANONICAL_TARGET

# Dynamic libs does work right now. Unresolved symbol problem perhaps?
AC_LIBTOOL_WIN32_DLL
AM_PROG_LIBTOOL
AM_INIT_AUTOMAKE(SDLmm, $VERSION)
AC_PROG_CXX


AC_CHECK_LIB(m, sqrt)
AC_HEADER_STDC

AC_LANG_CPLUSPLUS
AM_PROG_CC_STDC
AC_OPT_FLAGS

SDLMM_CXXFLAGS="$SDLMM_CXXFLAGS $SDL_CFLAGS"
SDLMM_LIBS="-lSDLmm $SDL_LIBS"

AC_ARG_ENABLE(pedantic,[  --enable-pedantic       Use -pedantic and -Werror compile flags (with gcc)], [
if test "x${GXX-}" = xyes -a "$enable_pedantic" = "yes"; then
  AC_SYS_COMPILER_FLAG(-pedantic,pedantic,CXXFLAGS,no)
  AC_SYS_COMPILER_FLAG(-Werror,Werror,CXXFLAGS,no)
  AC_SYS_COMPILER_FLAG(-Wno-long-long,Wnolonglong,CXXFLAGS,no)
fi
], [])

AC_MSG_CHECKING(for assert() use)
AC_ARG_ENABLE(assertions,[  --disable-assertions  Disable the use of assert().], [
  if test "$enable_assertions" = "yes"; then
    AC_DEFINE(ASSERTIONS)
    AC_MSG_RESULT(enabled)
  else
    AC_MSG_RESULT(disabled)
  fi
], [
  AC_DEFINE(ASSERTIONS)
  AC_MSG_RESULT(enabled)
] )

# Set runtime shared library paths as needed

case "$target" in
    *-*-linux*)
      SDLMM_RLD_FLAGS="-Wl,-rpath,\${exec_prefix}/lib"
      ;;
    *-*-freebsd*)
      SDLMM_RLD_FLAGS="-Wl,-rpath,\${exec_prefix}/lib"
      ;;
    *-*-solaris*)
      SDLMM_RLD_FLAGS="-R\${exec_prefix}/lib"
      ;;
esac

AC_LANG_C
AM_PATH_SDL(1.2.0,:, AC_MSG_ERROR([*** SDL version 1.2.0 or newer not found!]))
AC_MSG_CHECKING(for install prefix)
if test "$prefix" = "NONE"; then
  prefix=`$SDL_CONFIG --prefix`
fi
AC_MSG_RESULT($prefix)

CXXFLAGS="-I$srcdir/src/ $CXXFLAGS $SDL_CFLAGS"
LIBS="$LIBS $SDL_LIBS"


if test "$DEBUG" = "yes";then
  echo "CXXFLAGS=$CXXFLAGS"
  echo "LDFLAGS=$LDFLAGS "
  echo "LIBS=$LIBS"
fi

AC_SUBST(SDLMM_LIBS)
AC_SUBST(SDLMM_CXXFLAGS)
AC_SUBST(SDLMM_RLD_FLAGS)

dnl  if we need this, use em.
dnl AC_CHECK_LIB(C, cin)
dnl AC_CHECK_LIB(g++, cin)
dnl C_CHECK_LIB(stdc++, cin)
dnl Digital Unix 4.0
dnl AC_CHECK_LIB(cxx, cin)
dnl AC_CHECK_LIB(cxxstd, __array_delete)

PATH=$srcdir:$PATH
export PATH

AC_OUTPUT(
	Makefile \
	src/Makefile \
	test/Makefile \
	docs/Makefile \
	docs/html/Makefile \
	docs/man/Makefile \
	docs/man/man3/Makefile \
	sdlmm-config \
	docs/sdlmm.doxy
, [chmod +x sdlmm-config])