dnl Configuration for Kamikaze
dnl ==========================

AC_INIT
AC_CONFIG_SRCDIR([configure.ac])
AM_INIT_AUTOMAKE(kamikaze, 0.2.1)
AC_CONFIG_HEADERS([config.h])

AC_ARG_ENABLE(client, [  --disable-client       Dont' build Client],, enable_client=yes)
AC_ARG_ENABLE(server, [  --disable-server       Dont' build Server],, enable_server=yes)

AC_PROG_CXX

dnl Check for Qt and KDE
dnl ====================

if test $enable_client = yes; then
  KDE_SET_PREFIX
  KDE_USE_QT(3)
  AC_CHECK_COMPILERS
  AC_ENABLE_SHARED(yes)
  AC_ENABLE_STATIC(no)
else
  AC_PROG_CC
  AC_HEADER_STDC
  AC_ENABLE_SHARED(yes)
  AC_ENABLE_STATIC(no)

  RANLIB="ranlib"
  AC_SUBST(RANLIB)
  qtfake_includes="-I \$(top_srcdir)/common/src/qt"
  AC_SUBST(qtfake_includes)
fi

AC_PROG_LIBTOOL

if test $enable_client = yes; then
  AC_PATH_KDE
  AC_KNEWSTUFF
fi

dnl Server side: ggzdmod and easysock
dnl =================================

if test $enable_client = yes || test $enable_server = yes; then
  AC_GGZ_INIT(defaults)
  AC_GGZ_LIBGGZ([], ignore)
fi
if test $enable_client = yes; then
  AC_GGZ_GGZMOD([], ignore)
  AC_GGZ_CONFIG([], ignore)

  if test "x$ggzmod_includes" != "x"; then
    AC_DEFINE_UNQUOTED(WITH_GGZ, 1, [Add GGZ functionality to the client.])
    ggz_enabled="yes"
  else
    ggz_enabled="no"
  fi
  client_enabled="yes"
else
  client_enabled="no"
fi
if test $enable_server = yes; then
  AC_GGZ_GGZDMOD([], ignore)
  AC_GGZ_SERVER([], force)

  if test "x$ggzdmod_includes" != "x"; then
    server_enabled="yes"
  else
    server_enabled="no"
  fi
else
  server_enabled="no"
fi

AM_CONDITIONAL([COMPILE_CLIENT], [test $client_enabled = yes])
AM_CONDITIONAL([COMPILE_SERVER], [test $server_enabled = yes])

dnl Be a bit more strict
dnl ====================

CXXFLAGS="-DKDE_NO_COMPAT -DQT_NO_COMPAT -Wall $CXXFLAGS "

dnl Write stuff
dnl ===========

AC_SUBST(CXXFLAGS)

AC_DEFINE_UNQUOTED(DATADIR, "${prefix}/share/apps/kamikaze", [Location of game data.])

AC_CONFIG_FILES([Makefile
	common/Makefile
	common/src/Makefile
	common/src/qt/Makefile
	common/levels/Makefile
	client/Makefile
	client/module.dsc
	client/doc/Makefile
	client/src/Makefile
	client/editor/Makefile
	client/pics/Makefile
	client/pics/theme-standard/Makefile
	client/pics/theme-desert/Makefile
	client/pics/theme-nerdworld/Makefile
	client/pics/theme-winter/Makefile
	client/po/Makefile
	client/po/de/Makefile
	server/Makefile
	server/kamikaze.dsc
	doc/Makefile
	doc/spec/Makefile
	doc/html/Makefile])
AC_OUTPUT

dnl Userland info
dnl =============

echo ""
echo "---------------------------------------------------"
echo ""
echo "Kamikaze is now configured, type 'make' to compile."
echo ""
echo "Client compilation: $client_enabled"
if test $client_enabled = yes; then
  echo "  GGZ support enabled: $ggz_enabled"
fi
echo "Server compilation: $server_enabled"
echo ""