dnl Build description for dkim-filter
dnl 
dnl NO USER SERVICEABLE PARTS INSIDE
dnl See the package README file for details.

include(confBUILDTOOLSDIR`/M4/switch.m4')


define(`confMT', `TRUE')
define(`confREQUIRE_LIBSM', `true')

APPENDDEF(`confLIBS', `-lssl -lcrypto')

ifdef(`bld_USE_ARLIB', `bldPUSH_SMLIB(`ar')', `')

bldPUSH_SMLIB(`sm')

bldPUSH_SMLIB(`dkim')
APPENDDEF(`confINCDIRS', `-I../libdkim/ ')

ifdef(`bld_VERIFY_DOMAINKEYS',`
APPENDDEF(`confENVDEF', `-DVERIFY_DOMAINKEYS ')
bldPUSH_SMLIB(`dk')
APPENDDEF(`confINCDIRS', `-I../libdk/ ')', `')


ifdef(`bld_dkim_filter_INCDIRS', `APPENDDEF(`confINCDIRS', bld_dkim_filter_INCDIRS)', `')
ifdef(`bld_dkim_filter_LIBDIRS', `APPENDDEF(`confLIBDIRS', bld_dkim_filter_LIBDIRS)', `')
ifdef(`conf_dkim_filter_ENVDEF', `APPENDDEF(`confENVDEF', conf_dkim_filter_ENVDEF)', `')
ifdef(`conf_dkim_filter_LIBS', `APPENDDEF(`confLIBS', conf_dkim_filter_LIBS)', `')


bldPRODUCT_START(`executable', `dkim-filter')
define(`bldINSTALL_DIR', `E')
define(`bldSOURCES', `config.c dkim-ar.c dkim-filter.c stats.c test.c util.c ')
PREPENDDEF(`confLIBS', `-lmilter ')
bldPRODUCT_END

ifelse(index(confENVDEF, `-D_FFR_STATS'), -1, `', `
bldPRODUCT_START(`executable', `dkim-stats')
define(`bldINSTALL_DIR', `U')
define(`bldSOURCES', `dkim-stats.c ')
bldPRODUCT_END
')

dnl Install code for dkim-genkey is in here
bldPRODUCT_START(`executable', `dkim-testkey')
define(`bldINSTALL_DIR', `U')
define(`bldSOURCES', `dkim-testkey.c ')
bldPUSH_INSTALL_TARGET(`install-genkey')
divert(bldTARGETS_SECTION)

install-genkey:
	${INSTALL} -c -o ${UBINOWN} -g ${UBINGRP} -m 555 ${SRCDIR}/dkim-filter/dkim-genkey.sh ${DESTDIR}${UBINDIR}/dkim-genkey

divert(0)
bldPRODUCT_END

bldPRODUCT_START(`executable', `dkim-testssp')
define(`bldINSTALL_DIR', `U')
define(`bldSOURCES', `dkim-testssp.c ')
bldPRODUCT_END

bldPRODUCT_START(`manpage', `dkim-filter')
define(`bldSOURCES', `dkim-filter.conf.5 dkim-filter.8 dkim-genkey.8 dkim-stats.8 dkim-testkey.8 dkim-testssp.8')
bldPRODUCT_END

bldFINISH