dnl Configure script for Pointless Window Manager
dnl Copyright 1999 Peter Liljenberg.  GPL, see file COPYING
dnl $Id: configure.in,v 1.4 2001/12/06 11:08:08 petli Exp $

AC_INIT(plwm/wmanager.py)

PLWM=examples/examplewm.py
AC_SUBST(PLWM)
AC_ARG_ENABLE(plwm,
[  --enable-plwm[=script]  Install script as plwm, [script=examples/examplewm.py]],
[test "$enableval" != "yes" && PLWM=$enableval])
	      
WMM=utils/wmm.py
AC_SUBST(WMM)
AC_ARG_ENABLE(wmm,
[  --disable-wmm           Do not install the Window Manager Manager],
[test "$enableval" = "no" && WMM=no])

INSPECT_PLWM=utils/inspect_plwm.py
AC_SUBST(INSPECT_PLWM)
AC_ARG_ENABLE(inspect_plwm,
[  --disable-inspect       Do not install the PLWM inspect client],
[test "$enableval" = "no" && INSPECT_PLWM=no])


AC_ARG_WITH(python,
[  --with-python=binary   The path to the Python binary
                          (e.g. /usr/local/bin/python)])

AC_ARG_WITH(python-path,
[  --with-python-path=dir  Where the plwm package will be installed.
                          Default is to search sys.path for a suitable
			  directory.])

AC_ARG_WITH(python-xlib,
[  --with-python-xlib=dir  The catalog containing the Python X Library.
                          If omitted, it is assumed to be located in
			  Python's sys.path.])
			  
AC_PROG_INSTALL

if test -n "$with_python"
then
    AC_MSG_CHECKING([for Python])
    PYTHON="$with_python"
    AC_SUBST(PYTHON)
    AC_MSG_RESULT($PYTHON)
else
    AC_PATH_PROG(PYTHON, python)
fi

AC_MSG_CHECKING([for Python site package path])

if test -n "$with_python_path"
then
    PYTHON_SITE_PATH="$with_python_path"
else
    AC_CACHE_VAL(plwm_cv_path_python_path,
[plwm_cv_path_python_path=`$PYTHON <<EOF
[import sys, os

sitep = 'site-packages'
for p in sys.path:
    if p[-len(sitep):] == sitep:
        print p
        sys.exit(0)

for p in sys.path:
    if p != '':
        print os.path.join(p, 'site-packages')
        sys.exit(0)
]
EOF`])

    test -z "$plwm_cv_path_python_path" && AC_MSG_ERROR([no path])
    PYTHON_SITE_PATH="$plwm_cv_path_python_path"
fi

AC_MSG_RESULT($PYTHON_SITE_PATH)
AC_SUBST(PYTHON_SITE_PATH)


if test -n "$with_python_xlib"
then
    PYTHON_XLIB="$with_python_xlib"
else
    AC_MSG_CHECKING([for Python X Library])
    if "$PYTHON" -c "import Xlib" 2>/dev/null
    then
       AC_MSG_RESULT(ok)
       PYTHON_XLIB=""
    else    
       AC_MSG_ERROR([not found in sys.path])
    fi
fi
AC_SUBST(PYTHON_XLIB)


AC_OUTPUT(Makefile install-plwm.sh plwm/xlibpath.py)
AC_OUTPUT_COMMANDS([chmod 755 install-plwm.sh])